next up previous contents
Next: Partially Supported Beam Up: The Computer Algebra Previous: The Computer Algebra

Beam on Elastic Foundation

We can use Mathematica to sketch the situation:

    <<Graphics`Arrow` 
    beam = { Thickness[0.02],  
             Line[{ {-4,-1}, {4,-1}, {4,1}, {-4,1}, {-4,-1} }] }; 
    foundation = { GrayLevel[0.8], Rectangle[ {-5,-5}, {5,-1}] }; 
    xArrow = Arrow[{-4,0}, {5, 0}]; 
    wArrow = Arrow[{-4,0}, {-4,-4}]; 
    leftPointLoad  = Arrow[{-2.5,2.5}, {-2.5,1}]; 
    rightPointLoad = Arrow[{ 2.5,2.5}, { 2.5,1}]; 
    LArrow = { Arrow[{0,-2}, {4, -2}], Arrow[{0,-2}, {-4,-2}] }; 
    lArrow = { Arrow[{0, 2}, {2.5,2}], Arrow[{0, 2},{-2.5,2}] }; 
    aArrows = {  
      Arrow[{ 2.5,2}, { 4,2}], Arrow[{ 4,2}, { 2.5,2}], 
      Arrow[{-2.5,2}, {-4,2}], Arrow[{-4,2}, {-2.5,2}]  
              }; 
    text = {  
      Text[ FontForm["x",{"Helvetica-Bold",14}], {5.5,0} ], 
      Text[ FontForm["w",{"Helvetica-Bold",14}], {-4,-4.5} ], 
      Text[ FontForm["L",{"Helvetica-Bold",14}], {0,-1.75} ], 
      Text[ FontForm["l",{"Helvetica-Bold",14}], {0,1.7} ], 
      Text[ FontForm["a",{"Helvetica-Bold",14}], {3.25,1.7} ], 
      Text[ FontForm["a",{"Helvetica-Bold",14}], {-3.25,1.7} ], 
      Text[ FontForm["F",{"Helvetica-Bold",14}], {-2.5,2.8} ], 
      Text[ FontForm["F",{"Helvetica-Bold",14}], { 2.5,2.8} ]  
          }; 
    Show[Graphics[ { foundation, beam, xArrow, wArrow, leftPointLoad, 
      rightPointLoad, LArrow, lArrow, aArrows, text }, 
      PlotRange -> All ]];
It may look overwhelming, but it is merely a specification of the graphics objects and it will produce Figure 6.3.

 
Figure 6.3: Beam on Elastic Foundation 

By the way, this is also how Figure 6.1 was created.

The differential equation 6.6 is entered in Mathematica as

    4 beta^4 w[x] + D[w[x],{x,4}] == load / EI
and displays as
          4         (4)       load
    4 beta  w[x] + w   [x] == ----
                               EI
The load is in this case
    <<Calculus`DiracDelta` 
    load = F DiracDelta[x-a] +   F DiracDelta[x-a-l];
The Mathematica command DSolve is powerful enough to solve the differential equation. the result is after some simplification
    d1 Cos[beta x]       beta x               d2 Sin[beta x]
    -------------- + d3 E       Cos[beta x] + -------------- + 
        beta x                                    beta x
       E                                         E
 
          beta x
      d4 E       Sin[beta x] + 
 
        beta (a - x)
      (E             F (Cos[beta (-a + x)] - 
 
            2 beta (-a + x)
           E                Cos[beta (-a + x)] + 
 
           Sin[beta (-a + x)] + 
 
            2 beta (-a + x)
           E                Sin[beta (-a + x)]) UnitStep[-a + x]
 
                    3
         ) / (8 beta  EI) + (F 
 
         (-Cos[beta (a + l - x)] + 
 
            2 beta (a + l - x)
           E                   Cos[beta (a + l - x)] - 
 
           Sin[beta (a + l - x)] - 
 
            2 beta (a + l - x)
           E                   Sin[beta (a + l - x)]) 
 
                                        3  beta (a + l - x)
         UnitStep[-a - l + x]) / (8 beta  E                 EI)
We can then define the deflection, slope, bending moment, and shear force functions.
    W[x_] = %;       
    H[x_] = D[ W[x], x ]; 
    M[x_] = -EI D[ H[x], x ]; 
    Q[x_] = D[ M[x], x ];
The ends of the beam are free so that the bending moment and shear force are at these points equal to zero. This gives us 4 equations in the four unknowns d1, d2, d3, and d4, which Mathematica can solve. Even after simplification the results are large: typically formulae that fill one A4 page.

Instead of a we may also use in the formulae the indeterminates l and L via the relation . Furthermore, if we take concrete values for the unknowns, says , , , , and , then the general solution specializes to

    {d1 -> 0.537024, d2 -> 0.216867, d3 -> 0.970758, 
     
     d4 -> 0.216867}
We define a new plot routine to plot the graphs of the beam functions in our downward oriented coordinate system. This shows a bit of Mathematica's programming facilities.
    myPlot[ function_, domain_, options___ ] :=  
    Module[ {picture, range, markers}, 
    picture = Plot[ function, domain, options, 
      DisplayFunction -> Identity ]; 
    range = FullOptions[ picture, PlotRange ]; 
    range = { range[[1]], { - range[[2,2]], - range[[2,1]] } }; 
    picture = Plot[ -function, domain, PlotRange -> range, options, 
      DisplayFunction -> Identity ]; 
    markers = FullOptions[ picture, Ticks ]; 
    markers = {  
      Partition[Flatten[  
        Map[ ( If[ NumberQ[#[[2]]], {#[[1]],#[[2]]},{} ] )&,  
        markers[[1]] ] ], {2} ], 
      Partition[Flatten[  
        Map[ ( If[ NumberQ[#[[2]]], {#[[1]],-#[[2]]},{} ] )&,  
        markers[[2]] ] ], {2} ]  
              };  
    Show[ picture,  Ticks -> markers, PlotRange -> range, options, 
      DisplayFunction -> $DisplayFunction   ] 
    ];
So, this procedure is used to graph the deflection, slope, bending moment, and shear force of the beam.

 
Figure 6.4: Deflection of Supported Beam 

 
Figure 6.5: Slope of Supported Beam 

 
Figure 6.6: Bending Moment of Supported Beam 

 
Figure 6.7: Shear Force of Supported Beam 

Notice that in the solution method we have nowhere used the symmetry of the problem. Therefore, the symmetry shown in the graphs supports the correctness of the solution.

Having solved the general problem with indeterminates instead of concrete values allows us to analyze the dependency of the solution on certain parameters. For example, we could look at the dependency of the deflection on the stiffness of the foundation, i.e., on the parameter . We could make a surface plot or have an animation showing this dependency. Below is a picture consisting of four graphs from an animation of the bending moment in which ranges from to . Going from left to right, and from top to bottom, you see that when the foundation becomes more stiff, the bending moment reduces and gets flatter in the middle.


Figure 6.8: Bending Moments for Different



next up previous contents
Next: Partially Supported Beam Up: The Computer Algebra Previous: The Computer Algebra



Andre Heck
Sun Apr 23 10:32:10 MDT 1995